#!/usr/bin/awk -f

# File name: magick.awk
# Purpose:   Generate an xml file suitable for ImageMagick.
# Date:      June 11, 2006
# Creator:   Robert Valliant
# Usage:     Called by driver script: makemagick.sh.
#
# Modifications:
#            August 1, 2007
#                Moved from '==' to '~' to ensure all cases caught.
#

BEGIN {
  afm = "";
  begin = "";
  fontname = "";
  family = "";
  subtype = "";
  style = "normal";
  stretch = "normal";
  foundry = "";
  format="type1";
  fn = ARGV[1];
  metrics = fn;
  sub(/.afm/,".pfb",fn);
  glyphs = fn;
  print "<type";
}
{
  sub(/\r/,"", $0);
  if (/FullName/)
	fullname = substr($0,index($0," ")+1);
  else if (/Weight/) {
	xweight = tolower(substr($0,index($0," ")+1));
	if (xweight ~ /normal/)
	  weight = 400;
	else if (xweight ~ /black/)
	  weight = 900;
	else if (xweight ~ /book/)
	  weight = 300;
	else if (xweight ~ /demibold/)
	  weight = 600;
	else if (xweight ~ /extrabold/)
	  weight = 800;
	else if (xweight ~ /ultrabold/)
	  weight = 950;
	else if (xweight ~ /bold/)
	  weight = 700;
	else if (xweight ~ /heavy/)
	  weight = 950;
	else if (xweight ~ /medium/)
	  weight = 500;
	else if (xweight ~ /ultralight/)
	  weight = 100;
	else if (xweight ~ /extralight/)
	  weight = 100;
	else if (xweight ~ /light/)
	  weight = 200;
	else
	  weight = 400;
  }
  else if (/^AFM/) {
	afm = $0;
  }
  else if (/FontName/) {
	name = substr($0,index($0," ")+1);
	subtype = tolower(name);
	if (subtype ~ /italic/) {
	  style = "italic";
	}
	else if (subtype ~ /oblique/) {
	  style = "oblique";
	}
	else if (subtype ~ /outline/) {
	  style = "outline";
	}
	else if (subtype ~ /script/) {
	  style = "script";
	}
	if (subtype ~ /extracondensed/) {
	  stretch = "extra-condensed";
	}
	else if (subtype ~ /condensed/) {
	  stretch = "condensed";
	}
	else if (subtype ~ /extended/) {
	  stretch="extended";
	}
	else if (subtype ~ /expanded/) {
	  stretch="expanded";
	}
	else if (subtype ~ /ultracompress/) {
	  stretch = "ultra-compressed";
	}
	else if (subtype ~ /compress/) {
	  stretch="compressed";
	}
  }
  else if (/FamilyName/) {
	family = substr($0,index($0," ")+1);
  }
}
END {
	print "  name=\"" name "\"";
	print "  fullname=\"" fullname "\"";
	print "  family=\"" family "\"";
	print "  foundry=\"" foundry "\"";
	print "  weight=\"" weight "\"";
	print "  style=\"" style "\"";
	print "  stretch=\"" stretch "\"";
	print "  format=\"type1\"";
	print "  metrics=\"" metrics "\"";
	print "  glyphs=\"" glyphs "\"";
	print "  />";
	style = "normal";
	stretch = "normal";
}